//水平右到左平移；续图方式；最左边移除，最右边增加

/*

wcon.data["title"]
wcon.data["lastBuildDate"]

wcon.data["item"][0]["title"]
wcon.data["item"][0]["image"]

*/

//import mx.transitions.*;
//import mx.transitions.easing.*;
var db;
var loopFunc;	//@@@
var loopIdx;	//@@@
var parent=_parent._parent._parent._parent._parent
var scrWidth = parent.sys.stageWidth
var scrHeight = parent.sys.stageHeight - 44

var idm = 0;	//index movieclip
var idx = 0;	//index data

var len = 6;	//显示的图片个数，数量不同重复补全
var speed = 1

var preMc;				//记录上一个加载完的MC
var preLoadBln = true;	//预载len数量的图片然后滚动

var status="PLAY"
function pause(){	status="PAUSE";}
function play(){	status="PLAY";}

function init(dat,func){	//@@@
	db = dat
	loopFunc=func						//@@@
	createEmptyMovieClip("con",0)
	loop()
}

function loop(){
	var p = con.createEmptyMovieClip("p_"+idm,idm)
	p.createEmptyMovieClip("con",0)
	p.con.createEmptyMovieClip("pic",0)	
	
	var conListener:Object = new Object();
	conListener.onLoadInit = function(target_mc:MovieClip) {
		if(target_mc._width>0){
			target_mc._parent._xscale = target_mc._parent._yscale = scrHeight/target_mc._parent._height * 100	//匹配高度
			if(preMc){	target_mc._parent._parent._x += (preMc._x + preMc._width + 1)	}
			preMc = target_mc._parent._parent
			
			idm++
			if(preLoadBln){			
				if( idm>=len ) {	//加载完毕，跳出
					preLoadBln = false;
					con.bound = scrWidth/2-con._width/2
					con.delMcIdx = 0
					mtran();			
					return null;
				}else{
					loop()
				}
			}
			
		}else{
			loop()
		}
	}
	
	var conLoader:MovieClipLoader = new MovieClipLoader();
	conLoader.addListener(conListener);
	
	if( idx>db["item"].length-1 ) idx=0
	conLoader.loadClip(db["item"][idx]["image"],p.con.pic);
	idx++;

}

function mtran(){
	con.onEnterFrame = function(){
		if(status=="PLAY"){
			var delMc = this['p_'+this.delMcIdx]
			if(delMc._width>0){						//暂停移动,等待加载完毕
				this._x -= speed;
				if(this._x<this.bound){
					this.bound -= delMc._width
					delMc.removeMovieClip()
					this.delMcIdx++
					loop()
				}
			}
			
		}
	}
}